BLUE引擎说明书
BLUE引擎说明书
脚本示例

鉴定师自定义脚本

鉴定师自定义 NPC 完整脚本：装备锻造界面、装备分解换卷轴碎片、属性鉴定与锁定、取回装备。

用途

鉴定师自定义 NPC 版：用 {AX=,AY=} 坐标自绘界面，把装备放入物品框后鉴定，随机获得最多 4 条鉴定属性（每条上限 3 点），可锁定 3 条属性，用卷轴碎片作材料；同时提供装备分解（沃玛/祈祷/魔血/虹魔/祖玛等按档兑换卷轴碎片）与取回装备。

参考脚本

(@storage @getback )
[@装备锻造]
{
#ACT
SetMerchantDlgImgName jds.png
#SAY
<COLOR=$ccffff 鉴宝是一门技术，更是一门艺术。宝物和普通装备{AX=144,AY=55}>
<COLOR=$ccffff 的区别，在于细微之间，有人说靠眼力，我觉得，应该{AX=120,AY=70}>
<COLOR=$ccffff 是靠心去感受。{AX=120,AY=85}>
<COLOR=$ccffff 给我一件装备我可以帮你鉴定它是否还有更大的潜能。{AX=120,AY=100}>
<COLOR=$ccffff 另外，我这里还可以将{AX=120,AY=115}><COLOR=clYellow 神兵进阶{AX=240,AY=115}><COLOR=$ccffff ，鉴定{AX=288,AY=115}><COLOR=$33ff66 普通属性{AX=324,AY=115}><COLOR=$ccffff 、和{AX=372,AY=115}>
<COLOR=clYellow 神秘属性{AX=120,AY=130}><COLOR=$ccffff ，以及改变神兵的外观。{AX=168,AY=130}>
<COLOR=clRed 鉴{AX=120,AY=170}><COLOR=$ccffff 鉴定结果：最多出现4 条鉴定属性，每条上限3 点。{AX=135,AY=170}>
<COLOR=clRed 定{AX=120,AY=185}><COLOR=$ccffff 锁定规则：可以锁定3 条鉴定属性，保持属性不变。{AX=135,AY=185}>
<COLOR=clRed 说{AX=120,AY=200}><COLOR=$ccffff 鉴定材料：可以使用1 个卷轴碎片，鉴定一次装备。{AX=135,AY=200}>
<COLOR=clRed 明{AX=120,AY=215}><COLOR=$ccffff 鉴定流程：先将装备放入物品框内，进入鉴定界面，{AX=135,AY=215}><COLOR=$ccffff 点击「开始鉴定」按钮，随机获得属性，{AX=195,AY=230}>
                                         <COLOR=$ccffff 需要的属性可以先锁定，确认后取回装备。{AX=195,AY=245}>
<PIC=jdbw.png,0,0,0,0,0,0,25,180 LABEL=@鉴定宝物>
<PIC=zbfj.png,0,0,0,0,0,0,25,210 LABEL=@装备分解>
<PIC=qhzb.png,0,0,0,0,0,0,25,240 LABEL=@取回装备>
;<PIC=sbjj.png,0,0,0,0,0,0,25,220 LABEL=@神兵进阶>
;<PIC=smsx.png,0,0,0,0,0,0,25,240 LABEL=@@SecretProperty>

[@装备分解]
<COLOR=$ccffff 鉴定装备需要消耗物品{AX=144,AY=55}><COLOR=clRed 卷轴碎片{AX=265,AY=55}><COLOR=$ccffff ，该碎片可以使用{AX=312,AY=55}>
<COLOR=clYellow 沃玛{AX=408,AY=55}><COLOR=$ccffff ，{AX=433,AY=55}>
<COLOR=clYellow 祈祷{AX=120,AY=70}><COLOR=$ccffff 、{AX=144,AY=70}>
<COLOR=clYellow 魔血{AX=157,AY=70}><COLOR=$ccffff 、{AX=179,AY=70}>
<COLOR=clYellow 虹魔{AX=192,AY=70}><COLOR=$ccffff 、{AX=214,AY=70}>
<COLOR=clYellow 祖玛{AX=227,AY=70}><COLOR=$ccffff ，等装备到我这里进行兑换。{AX=252,AY=70}>
<COLOR=$ccffff 如您的包裹里有贵重的首饰，请先存放仓库，避免操作失误，{AX=120,AY=90}>
<COLOR=$ccffff 被系统回收！{AX=120,AY=105}>
<COLOR=clYellow 祈祷首饰{AX=120,AY=170}><COLOR=$ccffff 可兑换:卷轴碎片X3{AX=170,AY=170}><COLOR=clYellow 魔血首饰{AX=285,AY=170}><COLOR=$ccffff 可兑换:卷轴碎片X6{AX=335,AY=170}>
<COLOR=clYellow 沃玛首饰{AX=120,AY=185}><COLOR=$ccffff 可兑换:卷轴碎片X6{AX=170,AY=185}><COLOR=clYellow 虹魔首饰{AX=285,AY=185}><COLOR=$ccffff 可兑换:卷轴碎片X6{AX=335,AY=185}>
<COLOR=clYellow 祈祷武器{AX=120,AY=200}><COLOR=$ccffff 可兑换:卷轴碎片X6{AX=170,AY=200}><COLOR=clYellow 祖玛首饰{AX=285,AY=200}><COLOR=$ccffff 可兑换:卷轴碎片X50{AX=335,AY=200}>
<COLOR=clYellow 沃玛武器{AX=120,AY=215}><COLOR=$ccffff 可兑换:卷轴碎片X8{AX=170,AY=215}><COLOR=clYellow 井中月等{AX=285,AY=215}><COLOR=$ccffff 可兑换:卷轴碎片X100{AX=335,AY=215}>
<PIC=jdbw.png,0,0,0,0,0,0,25,180 LABEL=@鉴定宝物>
<PIC=zbfj.png,0,0,0,0,0,0,25,210 LABEL=@装备分解>
<PIC=qhzb.png,0,0,0,0,0,0,25,240 LABEL=@取回装备>
<PIC=cfwp.png,0,0,0,0,0,0,150,135 LABEL=@storage>
<PIC=qhwp.png,0,0,0,0,0,0,340,135 LABEL=@getback>
<PIC=tjzb.png,0,0,0,0,0,0,240,240 LABEL=@兑换碎片>

[@兑换碎片]
#IF
CHECKLEVELEX > 0
#ACT
QUERYITEMDLG 请放入兑换装备 @兑换页面 0

[@兑换页面]
#IF(1)
CHECKDLGITEMNAME 井中月
CHECKDLGITEMNAME 骨玉权杖
CHECKDLGITEMNAME 无极棍
#ACT
sendmsg 1 非凡的玩家：<$USERNAME>，回收了【<$DLGITEMNAME>】，回收获得卷轴碎片：x100
INC G90 1
TAKEDLGITEM
GIVE 卷轴碎片 100
DELAYGOTO 1000 @兑换碎片
BREAK
#IF(1)
CHECKDLGITEMNAME 黑铁头盔
CHECKDLGITEMNAME 灵魂项链
CHECKDLGITEMNAME 三眼手镯
CHECKDLGITEMNAME 泰坦戒指
CHECKDLGITEMNAME 恶魔铃铛
CHECKDLGITEMNAME 龙之手镯
CHECKDLGITEMNAME 紫碧螺
CHECKDLGITEMNAME 绿色项链
CHECKDLGITEMNAME 骑士手镯
CHECKDLGITEMNAME 阎罗手套
CHECKDLGITEMNAME 力量戒指
#ACT
sendmsg 1 非凡的玩家：<$USERNAME>，回收了【<$DLGITEMNAME>】，回收获得卷轴碎片：x50
INC G89 1
TAKEDLGITEM
GIVE 卷轴碎片 50
DELAYGOTO 1000 @兑换碎片
BREAK
#IF(1)
CHECKDLGITEMNAME 炼狱
CHECKDLGITEMNAME 魔杖
CHECKDLGITEMNAME 银蛇
#ACT
INC G88 1
TAKEDLGITEM
GIVE 卷轴碎片 8
DELAYGOTO 1000 @兑换碎片
BREAK
#IF(1)
CHECKDLGITEMNAME 天珠项链
CHECKDLGITEMNAME 心灵手镯
CHECKDLGITEMNAME 铂金戒指
CHECKDLGITEMNAME 生命项链
CHECKDLGITEMNAME 思贝儿手镯
CHECKDLGITEMNAME 红宝石戒指
CHECKDLGITEMNAME 幽灵项链
CHECKDLGITEMNAME 幽灵手套
CHECKDLGITEMNAME 龙之戒指
#ACT
INC G88 1
TAKEDLGITEM
GIVE 卷轴碎片 6
DELAYGOTO 1000 @兑换碎片
BREAK
#IF(1)
CHECKDLGITEMNAME 祈祷项链
CHECKDLGITEMNAME 祈祷手镯
CHECKDLGITEMNAME 祈祷戒指
CHECKDLGITEMNAME 祈祷头盔
#ACT
TAKEDLGITEM
GIVE 卷轴碎片 3
DELAYGOTO 1000 @兑换碎片
BREAK
#IF(1)
CHECKDLGITEMNAME 祈祷之刃
CHECKDLGITEMNAME 魔血手镯
CHECKDLGITEMNAME 魔血戒指
CHECKDLGITEMNAME 魔血项链
CHECKDLGITEMNAME 虹魔手镯
CHECKDLGITEMNAME 虹魔戒指
CHECKDLGITEMNAME 虹魔项链
#ACT
TAKEDLGITEM
GIVE 卷轴碎片 6
DELAYGOTO 1000 @兑换碎片
BREAK

[@storage]
#IF
CHECKLEVELEX > 0
#ACT
SetMerchantDlgImgName 1111.png
#SAY
需要保管什么东西?\ \
<返回/@首页>

[@getback]
#IF
CHECKLEVELEX > 0
#ACT
SetMerchantDlgImgName 1111.png
#SAY
请看目录决定找什么东西.\ \ \
<返回/@首页>

[@首页]
#IF
CHECKLEVELEX > 0
#ACT
SetMerchantDlgImgName jds.png
DELAYGOTO 1 @装备分解
CLOSE
BREAK

[@鉴定宝物]
#IF
CHECKLEVELEX > 0
Compval <$HASH(H_角色数据)<$USERNAME>_是否取回> = 0
#ACT
QUERYITEMDLG 请先放入装备 @鉴定页面 0
#ELSEACT
MESSAGEBOX 对不起，您鉴定的【<$HASH(H_角色数据)<$USERNAME>_装备名称>】还未取回！\　\请先取回已鉴定的装备。
BREAK

[@鉴定页面]
#IF
CHECKSTRINGLIST ..\QuestDiary\鉴定数据\禁止鉴定.txt <$DLGITEMNAME> hardDisk
#ACT
MESSAGEBOX 对不起，<$DLGITEMNAME>，不可鉴定！
CLOSE
BREAK

#IF
CHECKDLGITEMTYPE WEAPON
#ACT
GETDLGITEMID P9
GETDLGITEMVALUE M30 0
GETDLGITEMVALUE M31 1
GETDLGITEMVALUE M32 2
GETDLGITEMVALUE M33 3
GETDLGITEMVALUE M34 4
GETDLGITEMVALUE M35 5
GETDLGITEMVALUE M36 6
GETDLGITEMVALUE M37 7
GETDLGITEMVALUE M38 14
GETDLGITEMVALUE M39 15
Hash H_角色数据 Set <$USERNAME>_鉴定编号 <$STR(P9)>
Hash H_角色数据 Set <$USERNAME>_装备名称 <$DLGITEMNAME>
Hash H_角色数据 Set <$USERNAME>_装备类型 武器
Hash H_角色数据 Set <$USERNAME>_攻击 <$STR(M30)>
Hash H_角色数据 Set <$USERNAME>_魔法 <$STR(M31)>
Hash H_角色数据 Set <$USERNAME>_道术 <$STR(M32)>
Hash H_角色数据 Set <$USERNAME>_幸运 <$STR(M33)>
Hash H_角色数据 Set <$USERNAME>_诅咒 <$STR(M34)>
Hash H_角色数据 Set <$USERNAME>_准确 <$STR(M35)>
Hash H_角色数据 Set <$USERNAME>_攻击速度 <$STR(M36)>
Hash H_角色数据 Set <$USERNAME>_强度 <$STR(M37)>
Hash H_角色数据 Set <$USERNAME>_持久下限 <$STR(M38)>
Hash H_角色数据 Set <$USERNAME>_持久上限 <$STR(M39)>
Hash H_角色数据 Set <$USERNAME>_是否取回 1
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv
MOV M30 0
MOV M31 0
MOV M32 0
MOV M33 0
MOV M34 0
MOV M35 0
MOV M36 0
MOV M37 0
MOV M38 0
MOV M39 0
TAKEDLGITEM
DELAYGOTO 1 @显示鉴定
CLOSE
BREAK

#IF
CHECKDLGITEMTYPE DRESS
#ACT
GETDLGITEMID P9
GETDLGITEMVALUE M30 0
GETDLGITEMVALUE M31 1
GETDLGITEMVALUE M32 2
GETDLGITEMVALUE M33 3
GETDLGITEMVALUE M34 4
GETDLGITEMVALUE M35 14
GETDLGITEMVALUE M36 15
Hash H_角色数据 Set <$USERNAME>_鉴定编号  <$STR(P9)>
Hash H_角色数据 Set <$USERNAME>_装备名称 <$DLGITEMNAME>
Hash H_角色数据 Set <$USERNAME>_装备类型 服饰
Hash H_角色数据 Set <$USERNAME>_防御 <$STR(M30)>
Hash H_角色数据 Set <$USERNAME>_魔御 <$STR(M31)>
Hash H_角色数据 Set <$USERNAME>_攻击 <$STR(M32)>
Hash H_角色数据 Set <$USERNAME>_魔法 <$STR(M33)>
Hash H_角色数据 Set <$USERNAME>_道术 <$STR(M34)>
Hash H_角色数据 Set <$USERNAME>_持久下限 <$STR(M38)>
Hash H_角色数据 Set <$USERNAME>_持久上限 <$STR(M39)>
Hash H_角色数据 Set <$USERNAME>_是否取回 1
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv
MOV M30 0
MOV M31 0
MOV M32 0
MOV M33 0
MOV M34 0
MOV M35 0
MOV M36 0
TAKEDLGITEM
DELAYGOTO 1 @显示鉴定
CLOSE
BREAK

[@显示鉴定]
#IF
CHECKSTRINGLIST ..\QuestDiary\鉴定数据\装备idx.txt <$STR(P9)> hardDisk
#ACT
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性名称1 S67
Hash H_角色数据 Set <$USERNAME>_属性名称1 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性名称2 S67
Hash H_角色数据 Set <$USERNAME>_属性名称2 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性名称3 S67
Hash H_角色数据 Set <$USERNAME>_属性名称3 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性名称4 S67
Hash H_角色数据 Set <$USERNAME>_属性名称4 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性位置1 S67
Hash H_角色数据 Set <$USERNAME>_属性位置1 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性位置2 S67
Hash H_角色数据 Set <$USERNAME>_属性位置2 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性位置3 S67
Hash H_角色数据 Set <$USERNAME>_属性位置3 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性位置4 S67
Hash H_角色数据 Set <$USERNAME>_属性位置4 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性点数1 S67
Hash H_角色数据 Set <$USERNAME>_属性点数1 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性点数2 S67
Hash H_角色数据 Set <$USERNAME>_属性点数2 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性点数3 S67
Hash H_角色数据 Set <$USERNAME>_属性点数3 <$STR(S67)>
INI_READ_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$STR(P9)> 属性点数4 S67
Hash H_角色数据 Set <$USERNAME>_属性点数4 <$STR(S67)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv
DELLINELIST ..\QuestDiary\鉴定数据\装备idx.txt <$STR(P9)> hardDisk

#IF
EQUAL D62 3
#ACT
MOV D63 150
#IF
EQUAL D62 2
#ACT
MOV D63 100
#IF
EQUAL D62 1
#ACT
MOV D63 50
#IF
EQUAL D62 0
#ACT
MOV D63 0
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 1
#SAY
<PIC=ui1,3183,0,0,0,0,0,133,250>
<PIC=prguse2,229,0,0,0,0,0,130,247>
<材料不足时，使用10元宝购买{AX=150,AY=247}/@元宝解锁>
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 0
#SAY
<PIC=ui1,3183,0,0,0,0,0,133,250>
<PIC=prguse2,228,0,0,0,0,0,130,247>
<材料不足时，使用10元宝购买{AX=150,AY=247}/@元宝购买>
#IF
#SAY
<COLOR=$ccffff 部分属性介绍：{AX=120,AY=170}>
<COLOR=$ccffff 强身等级：根据职业增加对应的HP值。{AX=120,AY=185}>
<COLOR=$ccffff 聚魔等级：根据职业增加对应的MP值。{AX=120,AY=200}>
<COLOR=$ccffff 主 属 性：根据职业增加对应的攻击力上限{AX=120,AY=215}>
<COLOR=$ccffff 和一半下限。{AX=180,AY=230}>
<COLOR=$ccffff 每次鉴定需要10个卷轴碎片，卷轴不够，可用元宝代替。{AX=110,AY=5}>
<COLOR=$ccffff 锁定属性花费:1条=50元宝，2条=100元宝，3条=150元宝。{AX=110,AY=20}>
<PIC=jdbw.png,0,0,0,0,0,0,25,180 LABEL=@显示鉴定>
<PIC=zbfj.png,0,0,0,0,0,0,25,210 LABEL=@装备分解>
<PIC=qhzb.png,0,0,0,0,0,0,25,240 LABEL=@取回装备>
;<PIC=sbjj.png,0,0,0,0,0,0,25,220 LABEL=@神兵进阶>
;<PIC=smsx.png,0,0,0,0,0,0,25,240 LABEL=@@SecretProperty>
<PIC=ksjd.png,0,0,0,0,0,0,360,180 LABEL=@开始鉴定>
<PIC=qhzb.png,0,0,0,0,0,0,360,230 LABEL=@取回装备>
锁定属性：<$STR(D62)>{AX=210,AY=80}\
<COLOR=$ccffff 锁定花费：{AX=210,AY=100}><$STR(D63)>{AX=270,AY=100,C=$ccffff}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 1
#SAY
<PIC=ui1,3183,0,0,0,0,0,138,63>
<PIC=prguse2,229,0,0,0,0,0,150,60 LABEL=@解锁1>
<$HASH(H_角色数据)<$USERNAME>_属性名称1><$HASH(H_角色数据)<$USERNAME>_属性点数1>{AX=170,AY=60,c=clRed}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 1
#SAY
<PIC=ui1,3183,0,0,0,0,0,268,63>
<PIC=prguse2,229,0,0,0,0,0,280,60 LABEL=@解锁2>
<$HASH(H_角色数据)<$USERNAME>_属性名称2><$HASH(H_角色数据)<$USERNAME>_属性点数2>{AX=300,AY=60,c=clRed}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 1
#SAY
<PIC=ui1,3183,0,0,0,0,0,138,123>
<PIC=prguse2,229,0,0,0,0,0,150,120 LABEL=@解锁3>
<$HASH(H_角色数据)<$USERNAME>_属性名称3><$HASH(H_角色数据)<$USERNAME>_属性点数3>{AX=170,AY=120,c=clRed}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 1
#SAY
<PIC=ui1,3183,0,0,0,0,0,268,123>
<PIC=prguse2,229,0,0,0,0,0,280,120 LABEL=@解锁4>
<$HASH(H_角色数据)<$USERNAME>_属性名称4><$HASH(H_角色数据)<$USERNAME>_属性点数4>{AX=300,AY=120,c=clRed}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_属性位置1> > 0
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 0
#SAY
<PIC=prguse2,228,0,0,0,0,0,150,60 LABEL=@锁定1>
<$HASH(H_角色数据)<$USERNAME>_属性名称1><$HASH(H_角色数据)<$USERNAME>_属性点数1>{AX=170,AY=60,c=clYellow}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_属性位置2> > 0
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 0
#SAY
<PIC=prguse2,228,0,0,0,0,0,280,60 LABEL=@锁定2>
<$HASH(H_角色数据)<$USERNAME>_属性名称2><$HASH(H_角色数据)<$USERNAME>_属性点数2>{AX=300,AY=60,c=clYellow}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_属性位置3> > 0
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 0
#SAY
<PIC=prguse2,228,0,0,0,0,0,150,120 LABEL=@锁定3>
<$HASH(H_角色数据)<$USERNAME>_属性名称3><$HASH(H_角色数据)<$USERNAME>_属性点数3>{AX=170,AY=120,c=clYellow}\
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_属性位置4> > 0
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 0
#SAY
<PIC=prguse2,228,0,0,0,0,0,280,120 LABEL=@锁定4>
<$HASH(H_角色数据)<$USERNAME>_属性名称4><$HASH(H_角色数据)<$USERNAME>_属性点数4>{AX=300,AY=120,c=clYellow}\

[@取回装备]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_是否取回> = 0
#ACT
MESSAGEBOX 对不起，您没有可取回的鉴定装备！
BREAK

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_是否取回> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 武器
#ACT
GIVEEX <$HASH(H_角色数据)<$USERNAME>_装备名称> 1 0=<$HASH(H_角色数据)<$USERNAME>_攻击>,1=<$HASH(H_角色数据)<$USERNAME>_魔法>,2=<$HASH(H_角色数据)<$USERNAME>_道术>,3=<$HASH(H_角色数据)<$USERNAME>_幸运>,4=<$HASH(H_角色数据)<$USERNAME>_诅咒>,5=<$HASH(H_角色数据)<$USERNAME>_准确>,6=<$HASH(H_角色数据)<$USERNAME>_攻击速度>,7=<$HASH(H_角色数据)<$USERNAME>_强度>,14=<$HASH(H_角色数据)<$USERNAME>_持久下限>,15=<$HASH(H_角色数据)<$USERNAME>_持久上限>, <$HASH(H_角色数据)<$USERNAME>_属性位置1>=<$HASH(H_角色数据)<$USERNAME>_属性点数1>,<$HASH(H_角色数据)<$USERNAME>_属性位置2>=<$HASH(H_角色数据)<$USERNAME>_属性点数2>,<$HASH(H_角色数据)<$USERNAME>_属性位置3>=<$HASH(H_角色数据)<$USERNAME>_属性点数3>,<$HASH(H_角色数据)<$USERNAME>_属性位置4>=<$HASH(H_角色数据)<$USERNAME>_属性点数4>|0=0,0=0,0=0,0=0|0|0|1
Hash H_角色数据 Set <$USERNAME>_取回编号 <$CURITEMID>
ADDLINELIST ..\QuestDiary\鉴定数据\装备IDX.txt <$CURITEMID> hardDisk
INI_ERASE_SECTION ..\QuestDiary\鉴定数据\已经鉴定.ini <$HASH(H_角色数据)<$USERNAME>_鉴定编号>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 鉴定人 <$USERNAME>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 装备名称 <$HASH(H_角色数据)<$USERNAME>_装备名称>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称1 <$HASH(H_角色数据)<$USERNAME>_属性名称1>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称2 <$HASH(H_角色数据)<$USERNAME>_属性名称2>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称3 <$HASH(H_角色数据)<$USERNAME>_属性名称3>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称4 <$HASH(H_角色数据)<$USERNAME>_属性名称4>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置1 <$HASH(H_角色数据)<$USERNAME>_属性位置1>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置2 <$HASH(H_角色数据)<$USERNAME>_属性位置2>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置3 <$HASH(H_角色数据)<$USERNAME>_属性位置3>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置4 <$HASH(H_角色数据)<$USERNAME>_属性位置4>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数1 <$HASH(H_角色数据)<$USERNAME>_属性点数1>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数2 <$HASH(H_角色数据)<$USERNAME>_属性点数2>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数3 <$HASH(H_角色数据)<$USERNAME>_属性点数3>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数4 <$HASH(H_角色数据)<$USERNAME>_属性点数4>
INI_SAVE ..\QuestDiary\鉴定数据\已经鉴定.ini
INI_RELOAD ..\QuestDiary\鉴定数据\已经鉴定.ini
MOV D62 0
MOV D63 0
Hash H_角色数据 Set <$USERNAME>_元宝购买 0
Hash H_角色数据 Set <$USERNAME>_锁定1 0
Hash H_角色数据 Set <$USERNAME>_锁定2 0
Hash H_角色数据 Set <$USERNAME>_锁定3 0
Hash H_角色数据 Set <$USERNAME>_锁定4 0
Hash H_角色数据 Set <$USERNAME>_装备名称 无
Hash H_角色数据 Set <$USERNAME>_属性名称1 无
Hash H_角色数据 Set <$USERNAME>_属性位置1 0
Hash H_角色数据 Set <$USERNAME>_属性点数1 0
Hash H_角色数据 Set <$USERNAME>_属性名称2 无
Hash H_角色数据 Set <$USERNAME>_属性位置2 0
Hash H_角色数据 Set <$USERNAME>_属性点数2 0
Hash H_角色数据 Set <$USERNAME>_属性名称3 无
Hash H_角色数据 Set <$USERNAME>_属性位置3 0
Hash H_角色数据 Set <$USERNAME>_属性点数3 0
Hash H_角色数据 Set <$USERNAME>_属性名称4 无
Hash H_角色数据 Set <$USERNAME>_属性位置4 0
Hash H_角色数据 Set <$USERNAME>_属性点数4 0
Hash H_角色数据 Set <$USERNAME>_是否取回 0
Hash H_角色数据 Set <$USERNAME>_装备名称 无
Hash H_角色数据 Set <$USERNAME>_装备类型 无
Hash H_角色数据 Set <$USERNAME>_防御 0
Hash H_角色数据 Set <$USERNAME>_魔御 0
Hash H_角色数据 Set <$USERNAME>_攻击 0
Hash H_角色数据 Set <$USERNAME>_魔法 0
Hash H_角色数据 Set <$USERNAME>_道术 0
Hash H_角色数据 Set <$USERNAME>_幸运 0
Hash H_角色数据 Set <$USERNAME>_诅咒 0
Hash H_角色数据 Set <$USERNAME>_准确 0
Hash H_角色数据 Set <$USERNAME>_攻击速度 0
Hash H_角色数据 Set <$USERNAME>_强度 0
Hash H_角色数据 Set <$USERNAME>_持久下限 0
Hash H_角色数据 Set <$USERNAME>_持久上限 0
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv
CLOSE
BREAK
BREAK
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_是否取回> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 服饰
#ACT
GIVEEX <$HASH(H_角色数据)<$USERNAME>_装备名称> 1 0=<$HASH(H_角色数据)<$USERNAME>_防御>,1=<$HASH(H_角色数据)<$USERNAME>_魔御>,2=<$HASH(H_角色数据)<$USERNAME>_攻击>,3=<$HASH(H_角色数据)<$USERNAME>_魔法>,4=<$HASH(H_角色数据)<$USERNAME>_道术>,14=<$HASH(H_角色数据)<$USERNAME>_持久下限>,15=<$HASH(H_角色数据)<$USERNAME>_持久上限)>, <$HASH(H_角色数据)<$USERNAME>_属性位置1>=<$HASH(H_角色数据)<$USERNAME>_属性点数1>,<$HASH(H_角色数据)<$USERNAME>_属性位置2>=<$HASH(H_角色数据)<$USERNAME>_属性点数2>,<$HASH(H_角色数据)<$USERNAME>_属性位置3>=<$HASH(H_角色数据)<$USERNAME>_属性点数3>,<$HASH(H_角色数据)<$USERNAME>_属性位置4>=<$HASH(H_角色数据)<$USERNAME>_属性点数4>|0=0,0=0,0=0,0=0|0|0|1
Hash H_角色数据 Set <$USERNAME>_取回编号 <$CURITEMID>
ADDLINELIST ..\QuestDiary\鉴定数据\装备IDX.txt <$CURITEMID> hardDisk
INI_ERASE_SECTION ..\QuestDiary\鉴定数据\已经鉴定.ini <$HASH(H_角色数据)<$USERNAME>_鉴定编号>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 鉴定人 <$USERNAME>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 装备名称 <$HASH(H_角色数据)<$USERNAME>_装备名称>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称1 <$HASH(H_角色数据)<$USERNAME>_属性名称1>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称2 <$HASH(H_角色数据)<$USERNAME>_属性名称2>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称3 <$HASH(H_角色数据)<$USERNAME>_属性名称3>
INI_WRITE_STRING ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性名称4 <$HASH(H_角色数据)<$USERNAME>_属性名称4>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置1 <$HASH(H_角色数据)<$USERNAME>_属性位置1>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置2 <$HASH(H_角色数据)<$USERNAME>_属性位置2>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置3 <$HASH(H_角色数据)<$USERNAME>_属性位置3>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性位置4 <$HASH(H_角色数据)<$USERNAME>_属性位置4>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数1 <$HASH(H_角色数据)<$USERNAME>_属性点数1>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数2 <$HASH(H_角色数据)<$USERNAME>_属性点数2>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数3 <$HASH(H_角色数据)<$USERNAME>_属性点数3>
INI_WRITE_INTEGER ..\QuestDiary\鉴定数据\已经鉴定.ini <$CURITEMID> 属性点数4 <$HASH(H_角色数据)<$USERNAME>_属性点数4>
INI_SAVE ..\QuestDiary\鉴定数据\已经鉴定.ini
INI_RELOAD ..\QuestDiary\鉴定数据\已经鉴定.ini
MOV D62 0
MOV D63 0
Hash H_角色数据 Set <$USERNAME>_元宝购买 0
Hash H_角色数据 Set <$USERNAME>_锁定1 0
Hash H_角色数据 Set <$USERNAME>_锁定2 0
Hash H_角色数据 Set <$USERNAME>_锁定3 0
Hash H_角色数据 Set <$USERNAME>_锁定4 0
Hash H_角色数据 Set <$USERNAME>_属性名称1 无
Hash H_角色数据 Set <$USERNAME>_属性位置1 0
Hash H_角色数据 Set <$USERNAME>_属性点数1 0
Hash H_角色数据 Set <$USERNAME>_属性名称2 无
Hash H_角色数据 Set <$USERNAME>_属性位置2 0
Hash H_角色数据 Set <$USERNAME>_属性点数2 0
Hash H_角色数据 Set <$USERNAME>_属性名称3 无
Hash H_角色数据 Set <$USERNAME>_属性位置3 0
Hash H_角色数据 Set <$USERNAME>_属性点数3 0
Hash H_角色数据 Set <$USERNAME>_属性名称4 无
Hash H_角色数据 Set <$USERNAME>_属性位置4 0
Hash H_角色数据 Set <$USERNAME>_属性点数4 0
Hash H_角色数据 Set <$USERNAME>_是否取回 0
Hash H_角色数据 Set <$USERNAME>_装备名称 无
Hash H_角色数据 Set <$USERNAME>_装备类型 无
Hash H_角色数据 Set <$USERNAME>_防御 0
Hash H_角色数据 Set <$USERNAME>_魔御 0
Hash H_角色数据 Set <$USERNAME>_攻击 0
Hash H_角色数据 Set <$USERNAME>_魔法 0
Hash H_角色数据 Set <$USERNAME>_道术 0
Hash H_角色数据 Set <$USERNAME>_幸运 0
Hash H_角色数据 Set <$USERNAME>_诅咒 0
Hash H_角色数据 Set <$USERNAME>_准确 0
Hash H_角色数据 Set <$USERNAME>_攻击速度 0
Hash H_角色数据 Set <$USERNAME>_强度 0
Hash H_角色数据 Set <$USERNAME>_持久下限 0
Hash H_角色数据 Set <$USERNAME>_持久上限 0
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv
CLOSE
BREAK
BREAK

[@开始鉴定]
#IF
CHECKLEVELEX > 0
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 无
#ACT
MESSAGEBOX 对不起，您目前没有鉴定装备。
BREAK

#IF
EQUAL D62 3
#ACT
MOV D63 150
#IF
EQUAL D62 2
#ACT
MOV D63 100
#IF
EQUAL D62 1
#ACT
MOV D63 50
#IF
EQUAL D62 0
#ACT
MOV D63 0

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 0
CHECKITEM 卷轴碎片 1
#ACT
TAKE 卷轴碎片 1
#ELSEIF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 1
#ACT
INC D63 10
#ELSEACT
MESSAGEBOX 对不起，您没有达到以下条件任意之一！\　\1、元宝不足！\2、材料不足！\　\如果您身上没有材料！可以勾选使用元宝购买！
BREAK

#IF
CHECKGAMEGOLD ? <$STR(D63)>
#ELSEACT
MESSAGEBOX 对不起，您没有【<$STR(D63)>】元宝！请充值！
BREAK

#IF
LARGE D62 0
CHECKGAMEGOLD ? <$STR(D63)>
#ACT
GAMEGOLD - <$STR(D63)>

#IF
EQUAL D62 0
CHECKGAMEGOLD ? <$STR(D63)>
#ACT
GAMEGOLD - <$STR(D63)>

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 武器
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 0
#ACT
MOV S15
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\武器.txt S15 hardDisk
StrTok S15 S20 =
StrTok S15 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置1 <$STR(S15)>
Hash H_角色数据 Set <$USERNAME>_属性名称1 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数1 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 武器
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 0
#ACT
MOV S16
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\武器.txt S16 hardDisk
StrTok S16 S20 =
StrTok S16 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置2 <$STR(S16)>
Hash H_角色数据 Set <$USERNAME>_属性名称2 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数2 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 武器
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 0
#ACT
MOV S17
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\武器.txt S17 hardDisk
StrTok S17 S20 =
StrTok S17 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置3 <$STR(S17)>
Hash H_角色数据 Set <$USERNAME>_属性名称3 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数3 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 武器
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 0
#ACT
MOV S18
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\武器.txt S18 hardDisk
StrTok S18 S20 =
StrTok S18 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置4 <$STR(S18)>
Hash H_角色数据 Set <$USERNAME>_属性名称4 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数4 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 服饰
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 0
#ACT
MOV S15
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\服饰.txt S15 hardDisk
StrTok S15 S20 =
StrTok S15 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置1 <$STR(S15)>
Hash H_角色数据 Set <$USERNAME>_属性名称1 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数1 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 服饰
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 0
#ACT
MOV S16
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\服饰.txt S16 hardDisk
StrTok S16 S20 =
StrTok S16 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置2 <$STR(S16)>
Hash H_角色数据 Set <$USERNAME>_属性名称2 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数2 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 服饰
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 0
#ACT
MOV S17
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\服饰.txt S17 hardDisk
StrTok S17 S20 =
StrTok S17 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置3 <$STR(S17)>
Hash H_角色数据 Set <$USERNAME>_属性名称3 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数3 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
Compval <$HASH(H_角色数据)<$USERNAME>_装备类型> = 服饰
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 1
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 0
#ACT
MOV S18
MOV S20
MOV S21
READRANDOMSTR ..\QuestDiary\鉴定数据\服饰.txt S18 hardDisk
StrTok S18 S20 =
StrTok S18 S21 =
Hash H_角色数据 Set <$USERNAME>_属性位置4 <$STR(S18)>
Hash H_角色数据 Set <$USERNAME>_属性名称4 <$STR(S20)>
Hash H_角色数据 Set <$USERNAME>_属性点数4 <$STR(S21)>
Hash H_角色数据 Save ..\QuestDiary\HumData\H_角色数据.csv

#IF
HAVEGUILD
#ACT
INI_RELOAD ..\QuestDiary\数据文件\消费记录\个人消费记录.ini HardDisk
INI_RELOAD ..\QuestDiary\数据文件\消费记录\行会消费记录.ini HardDisk
INTS  21 + <$STR(D63)>
GUILDBUILDPOINT + <$STR(D63)>
INI_WRITE_INTEGER_EX  ..\QuestDiary\数据文件\消费记录\行会消费记录.ini  行会消费 <$GUILDNAME> = <$GUILDBUILDPOINT>
INI_WRITE_INTEGER_EX  ..\QuestDiary\数据文件\消费记录\个人消费记录.ini  个人消费 <$USERNAME> = <$INTS21>
INI_RELOAD ..\QuestDiary\数据文件\消费记录\个人消费记录.ini HardDisk
INI_RELOAD ..\QuestDiary\数据文件\消费记录\行会消费记录.ini HardDisk
DELAYGOTO 1 @显示鉴定
BREAK

#IF
!HAVEGUILD
#ACT
INTS  21 + <$STR(D63)>
INI_RELOAD ..\QuestDiary\数据文件\消费记录\个人消费记录.ini HardDisk
INI_WRITE_INTEGER_EX  ..\QuestDiary\数据文件\消费记录\个人消费记录.ini  个人消费 <$USERNAME> = <$INTS21>
INI_RELOAD ..\QuestDiary\数据文件\消费记录\个人消费记录.ini HardDisk
DELAYGOTO 1 @显示鉴定
BREAK

[@元宝解锁]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 1
#ACT
Hash H_角色数据 Set <$USERNAME>_元宝购买 0
DELAYGOTO 1 @显示鉴定
BREAK

[@元宝购买]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_元宝购买> = 0
#ACT
Hash H_角色数据 Set <$USERNAME>_元宝购买 1
DELAYGOTO 1 @显示鉴定
BREAK

[@锁定1]
#IF
SMALL D62 4
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 0
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定1 1
INC D62 1
DELAYGOTO 1 @显示鉴定
#ELSEACT
MESSAGEBOX 对不起，您目前已经锁定【<$STR(D62)>】条属性，\　\最高只能锁定3条属性。
BREAK

[@锁定2]
#IF
SMALL D62 4
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 0
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定2 1
INC D62 1
DELAYGOTO 1 @显示鉴定
#ELSEACT
MESSAGEBOX 对不起，您目前已经锁定【<$STR(D62)>】条属性，\　\最高只能锁定3条属性。
BREAK

[@锁定3]
#IF
SMALL D62 4
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 0
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定3 1
INC D62 1
DELAYGOTO 1 @显示鉴定
#ELSEACT
MESSAGEBOX 对不起，您目前已经锁定【<$STR(D62)>】条属性，\　\最高只能锁定3条属性。
BREAK

[@锁定4]
#IF
SMALL D62 4
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 0
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定4 1
INC D62 1
DELAYGOTO 1 @显示鉴定
#ELSEACT
MESSAGEBOX 对不起，您目前已经锁定【<$STR(D62)>】条属性，\　\最高只能锁定3条属性。
BREAK

[@解锁1]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定1> = 1
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定1 0
DEC D62 1
DELAYGOTO 1 @显示鉴定

[@解锁2]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定2> = 1
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定2 0
DEC D62 1
DELAYGOTO 1 @显示鉴定

[@解锁3]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定3> = 1
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定3 0
DEC D62 1
DELAYGOTO 1 @显示鉴定

[@解锁4]
#IF
Compval <$HASH(H_角色数据)<$USERNAME>_锁定4> = 1
#ACT
Hash H_角色数据 Set <$USERNAME>_锁定4 0
DEC D62 1
DELAYGOTO 1 @显示鉴定
}

附属数据文件

QuestDiary\鉴定数据\禁止鉴定.txt

脚本用 CHECKSTRINGLIST ..\QuestDiary\鉴定数据\禁止鉴定.txt <$DLGITEMNAME> hardDisk 判断，列在这里的装备名一律不可鉴定（一行一个装备名）。

青铜头盔
魔法头盔
道士头盔
骷髅头盔
黑铁头盔
金项链
传统项链
白金项链
黑檀项链
黄色水晶项链
黑色水晶项链
白色虎齿项链
魔鬼项链
琥珀项链
凤凰明珠
灯笼项链
狂风项链
蓝翡翠项链
竹笛
放大镜
铁手镯
小手镯
皮制手套
银手镯
钢手镯
大手镯
躲避手链
夏普儿手镯
坚固手套
魔法手镯
辟邪手镯
道士手镯
黑檀手镯
魔力手镯
死神手套
金手镯
古铜戒指
六角戒指
玻璃戒指
牛角戒指
生铁戒指
蓝色水晶戒指
狂风戒指
蛇眼戒指
珍珠戒指
黑色水晶戒指
金戒指
魅力戒指
道德戒指
骷髅戒指
珊瑚戒指
降妖除魔戒指
蜡烛
火把
火炬
荣誉勋章11号
荣誉勋章12号
荣誉勋章13号
荣誉勋章14号
荣誉勋章15号
荣誉勋章21号
荣誉勋章22号
荣誉勋章23号
荣誉勋章24号
荣誉勋章25号
荣誉勋章31号
荣誉勋章32号
荣誉勋章33号
荣誉勋章34号
荣誉勋章35号
荣誉勋章41号
荣誉勋章42号
荣誉勋章43号
荣誉勋章44号
荣誉勋章45号
求婚戒指
技巧项链
探测项链
祈福项链
隐身戒指
麻痹戒指
复活戒指
护身戒指
超负载戒指
火焰戒指
防御戒指
传送戒指
幽灵项链
幽灵手套
龙之戒指
天珠项链
心灵手镯
铂金戒指
生命项链
思贝儿手镯
红宝石戒指
绿色项链
骑士手镯
阎罗手套
力量戒指
灵魂项链
三眼手镯
泰坦戒指
恶魔铃铛
龙之手镯
紫碧螺
魔血戒指
魔血手镯
魔血项链
虹魔戒指
虹魔手镯
虹魔项链
神秘戒指
神秘腰带
神秘头盔
记忆戒指
记忆项链
记忆手镯
记忆头盔
祈祷之刃
祈祷手镯
祈祷项链
祈祷戒指
祈祷头盔
圣战头盔
法神头盔
天尊头盔
圣战手镯
法神手镯
天尊手镯
圣战戒指
法神戒指
天尊戒指
圣战项链
法神项链
天尊项链
新手铁剑
新手半月
新手海魂
新手盔甲(男)
新手盔甲(女)
新手头盔
新手项链
新手手镯
新手戒指
战技盔甲(男)
战技盔甲(女)
魔技长袍(男)
魔技长袍(女)
道技战衣(男)
道技战衣(女)
战技之斧
魔技之杖
道技之剑
战技之链
道技之链
魔技之链
战技之镯
魔技之镯
道技之镯
战技之戒
魔技之戒
道技之戒
极·战技盔甲(男)
极·战技盔甲(女)
极·魔技长袍(男)
极·魔技长袍(女)
极·道技战衣(男)
极·道技战衣(女)
极·战技之斧
极·魔技之杖
极·道技之剑
极·战技之链
极·道技之链
极·魔技之链
极·战技之镯
极·魔技之镯
极·道技之镯
极·战技之戒
极·魔技之戒
极·道技之戒
经验勋章（初）
经验勋章（中）
经验勋章（高）

QuestDiary\鉴定数据\武器.txt

鉴定武器时用 READRANDOMSTR ..\QuestDiary\鉴定数据\武器.txt S15 hardDisk 随机取一条属性，再用 StrTok S15 S20 =、StrTok S15 S21 = 拆出属性名称、属性点数与属性位置。每行格式为 属性名+点数=属性位置 权重，例如 攻击上限+=1=1 11 表示属性名「攻击上限+」、点数 1、属性位置 1、权重 11；权重越大越容易被抽到（引擎 ReadRandomStr 的权重模式）。属性位置与装备属性位表一致，如 4=物防上限、5=魔防上限、25=麻痹抗性、28=主属性。

攻击上限+=1=1 11
魔法上限+=1=2 11
道术上限+=1=3 11
准确上限+=1=6 11
神圣伤害+=1=12 11
目标爆率+=1=15 11
装备防爆+=1=16 11
麻痹抗性+=1=25 11
强身等级+=1=26 11
聚魔等级+=1=27 11
主属性+=1=28 11
神圣伤害+=2=12 150
目标爆率+=2=15 150
装备防爆+=2=16 150
麻痹抗性+=2=25 150
强身等级+=2=26 150
聚魔等级+=2=27 150
攻击上限+=2=1 170
魔法上限+=2=2 170
道术上限+=2=3 170
准确上限+=2=6 180
主属性+=2=28 200
神圣伤害+=3=12 200
目标爆率+=3=15 200
装备防爆+=3=16 200
麻痹抗性+=3=25 200
强身等级+=3=26 200
聚魔等级+=3=27 200
攻击上限+=3=1 220
魔法上限+=3=2 220
道术上限+=3=3 220
准确上限+=3=6 230
主属性+=3=28 260
幸运属性+=1=9 500
诅咒属性+=1=10 500

QuestDiary\鉴定数据\服饰.txt

与 武器.txt 同一套读法，用于服饰（衣服）类装备的鉴定属性抽取：READRANDOMSTR ..\QuestDiary\鉴定数据\服饰.txt S15 hardDisk 后同样用 StrTok 按 = 拆分，每行格式也是 属性名+点数=属性位置 权重。

攻击上限+=1=1 11
魔法上限+=1=2 11
道术上限+=1=3 11
物防上限+=1=4 11
魔防上限+=1=5 11
目标爆率+=1=15 11
装备防爆+=1=16 11
麻痹抗性+=1=25 11
强身等级+=1=26 11
聚魔等级+=1=27 11
主属性+=1=28 11
毒物躲避+=1=29 11
中毒恢复+=1=30 11
物防上限+=2=4 120
魔防上限+=2=5 120
毒物躲避+=2=29 120
中毒恢复+=2=30 120
目标爆率+=2=15 150
装备防爆+=2=16 150
麻痹抗性+=2=25 150
强身等级+=2=26 150
聚魔等级+=2=27 150
攻击上限+=2=1 170
魔法上限+=2=2 170
道术上限+=2=3 170
物防上限+=3=4 180
魔防上限+=3=5 180
毒物躲避+=3=29 180
中毒恢复+=3=30 180
主属性+=2=28 200
目标爆率+=3=15 200
装备防爆+=3=16 200
麻痹抗性+=3=25 200
强身等级+=3=26 200
聚魔等级+=3=27 200
攻击上限+=3=1 220
魔法上限+=3=2 220
道术上限+=3=3 220
主属性+=3=28 260

QuestDiary\鉴定数据\已经鉴定.ini

以装备 ID 为节名保存这件装备鉴定出的属性：属性名称1~属性名称4、属性位置1~属性位置4、属性点数1~属性点数4；装备取回时还会写入 鉴定人 与 装备名称。脚本用 INI_READ_STRING 读取、INI_WRITE_STRING/INI_WRITE_INTEGER 写回、INI_ERASE_SECTION 清掉鉴定前的临时节。

[0]
鉴定人=狂道
装备名称=天师长袍
属性名称1=主属性+
属性名称2=麻痹抗性+
属性名称3=魔防上限+
属性名称4=主属性+
属性位置1=28
属性位置2=25
属性位置3=5
属性位置4=28
属性点数1=3
属性点数2=3
属性点数3=2
属性点数4=1

[6821162682449920]
鉴定人=狂道
装备名称=天尊道袍
属性名称1=主属性+
属性名称2=物防上限+
属性名称3=魔防上限+
属性名称4=道术上限+
属性位置1=28
属性位置2=4
属性位置3=5
属性位置4=3
属性点数1=3
属性点数2=2
属性点数3=2
属性点数4=2

[6821167371681792]
鉴定人=狂道
装备名称=法神披风
属性名称1=聚魔等级+
属性名称2=主属性+
属性名称3=主属性+
属性名称4=中毒恢复+
属性位置1=27
属性位置2=28
属性位置3=28
属性位置4=30
属性点数1=2
属性点数2=1
属性点数3=1
属性点数4=1

[6821186621407232]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=攻击上限+
属性名称2=攻击上限+
属性名称3=强身等级+
属性名称4=主属性+
属性位置1=1
属性位置2=1
属性位置3=26
属性位置4=28
属性点数1=3
属性点数2=3
属性点数3=3
属性点数4=1

[6821190311739392]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=目标爆率+
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=15
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=1
属性点数2=0
属性点数3=0
属性点数4=0

[6821193352544256]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=攻击上限+
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=1
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=1
属性点数2=0
属性点数3=0
属性点数4=0

[6821200055926784]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=无
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=0
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=0
属性点数2=0
属性点数3=0
属性点数4=0

[6821200551870464]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=无
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=0
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=0
属性点数2=0
属性点数3=0
属性点数4=0

[6821203160924160]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=无
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=0
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=0
属性点数2=0
属性点数3=0
属性点数4=0

[6821211141472256]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=强身等级+
属性名称2=神圣伤害+
属性名称3=主属性+
属性名称4=强身等级+
属性位置1=26
属性位置2=12
属性位置3=28
属性位置4=26
属性点数1=3
属性点数2=3
属性点数3=3
属性点数4=2

[6821216374325248]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=准确上限+
属性名称2=主属性+
属性名称3=攻击上限+
属性名称4=攻击上限+
属性位置1=6
属性位置2=28
属性位置3=1
属性位置4=1
属性点数1=2
属性点数2=1
属性点数3=1
属性点数4=1

[6821217088667648]
鉴定人=狂道
装备名称=裁决之杖
属性名称1=无
属性名称2=无
属性名称3=无
属性名称4=无
属性位置1=0
属性位置2=0
属性位置3=0
属性位置4=0
属性点数1=0
属性点数2=0
属性点数3=0
属性点数4=0

QuestDiary\鉴定数据\装备idx.txt

已鉴定但还没取回的装备 ID 名单。[@显示鉴定] 用 CHECKSTRINGLIST ..\QuestDiary\鉴定数据\装备idx.txt <$STR(P9)> hardDisk 判断这件装备是否已有鉴定结果，处理完用 DELLINELIST 删除；取回装备时再用 ADDLINELIST 追加（脚本里写作 装备IDX.txt，Windows 下与 装备idx.txt 是同一个文件）。

6821162682449920
6821167371681792
6821186621407232
6821190311739392
6821193352544256
6821200055926784
6821200551870464
6821203160924160
6821211141472256
6821216374325248
6821217088667648

QuestDiary\数据文件\鉴定数据.ini

同目录上层的占位文件，当前是 0 字节空文件。脚本实际读写的是 QuestDiary\鉴定数据\已经鉴定.ini，这个文件没有被使用。

关键点

  • 脚本顶部声明 (@storage @getback)，界面用 <PIC=文件名,...,LABEL=@标签> 自绘按钮，并用 SetMerchantDlgImgName jds.png 指定对话框底图。
  • 鉴定材料是卷轴碎片；装备分解用 QUERYITEMDLG 请放入兑换装备 @兑换页面 0 打开物品框，再用 CHECKDLGITEMNAME 逐档判断、TAKEDLGITEM 收走、GIVE 卷轴碎片 N 发放。
  • 回收时会用 sendmsg 1 全服播报回收信息，并把回收件数累加到 G90/G89/G88 等全局变量（可用于后续排行）。
  • 源文件有两处书写瑕疵，使用时需按实际变量名修正：[@取回装备] 的服饰分支用 GETDLGITEMVALUE M35 14、M36 15 读入持久下限/上限，写回时却用了 M38、M39（该分支从未赋值），会导致服饰取回后持久为 0；同一行的 15=<$HASH(H_角色数据)<$USERNAME>_持久上限)> 还多写了一个 )。
  • CHM 入口结构版（鉴定宝物、神秘属性、卷轴碎片、宝物品评、成长任务线）见 鉴定师脚本（系统版）。

相关阅读

拜师收徒脚本

拜师收徒、解除师徒关系的完整脚本，并含同文件的荣誉勋章兑换与修理段。

佣兵示例脚本

佣兵（角色交易/压卡）完整脚本：密保验证、两步验证与免验证三种制作路径。